[NNTP] BNF for the additions to the LIST capability

Julien ÉLIE julien at trigofacile.com
Thu Oct 15 13:50:32 PDT 2009


> I think it would be useful to document a few additions to the LIST capability:
>
> - LIST ACTIVE -> field status "j", "x" and "=news.group";
> - LIST DISTRIBUTIONS;
> - LIST MODERATORS;
> - LIST MOTD;
> - LIST SUBSCRIPTIONS.

Here is a proposal for the grammar.


3.  Augmented BNF Syntax for the New LIST Commands

   This section describes the formal syntax of the new LIST commands
   defined in this document using [RFC5234].  It extends the syntax in
   Section 9 of [RFC3977], and non-terminals not defined in this
   document are defined there.  The [RFC3977] ABNF should be imported
   first before attempting to validate these rules.

3.1.  Commands

   This syntax extends the non-terminal <list-arguments> which
   represents the keywords for the LIST command.

      list-arguments =/ "DISTRIBUTIONS" / "MODERATORS" /
              "MOTD" / "SUBSCRIPTIONS"

3.2.  Responses

   This syntax extends the non-terminals <newsgroup-status> and <list-
   content> which respectively represent the status field returned by
   the LIST ACTIVE command and the response contents for the LIST
   command.

      ; active
      newsgroup-status =/ %x6A / %x78 /   ; case-sensitive "j" and "x"
              newsgroup-alias
      newsgroup-alias =  "=" newsgroup-name

      ; distributions
      list-content =/ list-distributions-content
      list-distributions-content =
            *(distribution WS distribution-description CRLF)
      distribution-description = S-TEXT

      ; moderators
      list-content =/ list-moderators-content
      list-moderators-content =
            *(wildmat ":" moderators-address CRLF)
      moderators-address = S-TEXT

      ; motd
      list-content =/ list-motd-content
      list-motd-content = *(*U-CHAR CRLF)

      ; subscriptions
      list-content =/ list-subscriptions-content
      list-subscriptions-content = *(newsgroup-name CRLF)




** Is it OK?
Especially S-TEXT for distribution-description and moderators-address (?)

** Should other things be defined in that section?
Especially capability entries (?)  I see that RFC 3977 has
  list-capability = "LIST" 1*(WS keyword)
and defines nowhere an exhaustive list of such keywords, contrary to
  list-arguments = keyword [WS token]
  list-content = body
which are both extended with the exhaustive list of keywords and
responses.
That's why I think a capability section is not necessary, but I may be wrong.

** Should a capability be added to specify that the additions to the LIST ACTIVE
command are properly taken into account? ("j", "x" and "=news.group")
As a matter of fact, I do not see how to distinguish a news server which uses "j"
as a private value (allowed by RFC 3977) and a news server which uses "j" with
the meaning defined in an extension...

-- 
Julien ÉLIE

« L'art de la médecine consiste à distraire le malade
  pendant que la nature le guérit. » (Voltaire) 



More information about the ietf-nntp mailing list